WMI Tasks: Accounts and Domains

Account and domain administrative tasks obtain information such as the computer domain or the currently logged-on user. Many of these tasks are best performed with ADSI scripts. For more information and other examples, see the TechNet ScriptCenter Script Repository.

The script examples shown in this topic obtain data only from the local computer. For more information about how to use the script to obtain data from remote computers, see Connecting to WMI on a Remote Computer.

The following procedure describes how to run a script.

To run a script

Copy the code and save it in a file with a .vbs extension, such as filename.vbs. Ensure that your text editor does not add a .txt extension to the file.
Open a command prompt window and navigate to the directory where you saved the file.
Type cscript filename.vbs at the command prompt.
If you cannot access an event log, check to see if you are running from an Elevated command prompt. Some Event Log, such as the Security Event Log, may be protected by User Access Controls (UAC).

Note

By default, cscript displays the output of a script in the command prompt window. Because WMI scripts can produce large amounts of output, you might want to redirect the output to a file. Type cscript filename.vbs > outfile.txt at the command prompt to redirect the output of the filename.vbs script to outfile.txt.

The following table lists script examples that can be used to obtain various types of data from the local computer.

How do I... WMI classes or methods

...determine the domain in which a computer belongs?

Use the Win32_ComputerSystem class and check the value of the Domain property. You can also use the DNSDomain property in Win32_NetworkAdapterConfiguration.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings
Wscript.Echo "System Name: " & objComputer.Name
Wscript.Echo "Domain: " & objComputer.Domain
Next

PowerShell
`$computer = Get-WmiObject -Class Win32_ComputerSystem "System Name: {0}" -f $computer.name "Domain : {0}" -f $computer.domain`

using Microsoft.Management.Infrastructure;
...
CimSession session = CimSession.Create("localHost");
IEnumerable<CimInstance> queryInstance = session.QueryInstances(@"root\cimv2", "WQL", "SELECT * FROM Win32_ComputerSystem");
foreach (CimInstance cimObj in queryInstance)
{
Console.WriteLine(cimObj.CimInstanceProperties["Name"].ToString());
Console.WriteLine(cimObj.CimInstanceProperties["Domain"].ToString());
}

...determine whether a computer is a server or a workstation?

Use the Win32_ComputerSystem class and the DomainRole property.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colComputers = objWMIService.ExecQuery("Select DomainRole from Win32_ComputerSystem")
For Each objComputer in colComputers
 Select Case objComputer.DomainRole 
 Case 0 
 strComputerRole = "Standalone Workstation"
 Case 1 
 strComputerRole = "Member Workstation"
 Case 2
 strComputerRole = "Standalone Server"
 Case 3
 strComputerRole = "Member Server"
 Case 4
 strComputerRole = "Backup Domain Controller"
 Case 5
 strComputerRole = "Primary Domain Controller"
 End Select
 Wscript.Echo strComputerRole
Next

PowerShell

$Computer = Get-WmiObject -Class Win32_ComputerSystem 
"Computer &quot;{0}.{1}" is a: "-f $Computer.Name,$computer.domain
switch ($computer.DomainRole) {
0 {"Standalone Workstation"}
1 {"Member Workstation"}
2 {"Standalone Server"}
3 {"Member Server"}
4 {"Backup Domain Controller"}
5 {"Primary Domain Controller"}
}

...determine the computer name?

Use the Win32_ComputerSystem class and the Name property. You can also use the DNSHostName property in Win32_NetworkAdapterConfiguration.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objItem in colItems
 Wscript.Echo "Computer Name: " & objItem.Name
Next

PowerShell
`$Computer = Get-WmiObject -Class Win32_ComputerSystem "Computer Name is: {0}" -f $Computer.Name`

using Microsoft.Management.Infrastructure;
...
CimSession session = CimSession.Create("localHost");
IEnumerable<CimInstance> queryInstance = session.QueryInstances(@"root\cimv2", "WQL", "SELECT * FROM Win32_ComputerSystem");
foreach (CimInstance cimObj in queryInstance)
{
Console.WriteLine(cimObj.CimInstanceProperties["Name"].ToString());
}

...find the name of the person currently logged on to a computer?

Use the Win32_ComputerSystem class and the UserName property.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
Set colComputer = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
 
For Each objComputer in colComputer
 Wscript.Echo "User Name = " & objComputer.UserName & VBNewLine & "Computer Name = " & objComputer.Name
WScript.Echo objComputer.UserName
Next

PowerShell
`$computers = Get-WmiObject -Class Win32_ComputerSystem "Logged on user(s):" foreach($computer in $computers) { "User: {0}" -f $computer.UserName }`

using Microsoft.Management.Infrastructure;
...
CimSession session = CimSession.Create("localHost");
IEnumerable<CimInstance> queryInstance = session.QueryInstances(@"root\cimv2", "WQL", "SELECT * FROM Win32_ComputerSystem");
foreach (CimInstance cimObj in queryInstance)
{
Console.WriteLine("User Name: " + cimObj.CimInstanceProperties["UserName"].ToString());
}

...rename a computer?

Use the Win32_ComputerSystem class, and the Rename method.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colComputers = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colComputers
 errReturn = ObjComputer.Rename("NewName")
 WScript.Echo "Computer name is now " & objComputer.Name
Next

PowerShell

param (
[$String] $NewName = 'NewName',
[$string] $Comp = "."
}
<# Get computer object #>
$Computer = Get-WmiObject -Class Win32_ComputerSystem -ComputerName $comp
<# Rename the Computer #>
$Return = $Computer.Rename($NewName)
if ($return.ReturnValue -eq 0) {
"Computer name is now: $NewName"
" but you need to reboot first"
} else {
" RenameFailed, return code: {0}" -f $return.ReturnValue
}

...retrieve only local groups using WMI?

Use the Win32_Group class and include the following WHERE clause in your WQL query.

Where LocalAccount = True

strComputer = "."
Set objWMIService = GetObject( _
 "winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery _
 ("Select * from Win32_Group Where LocalAccount = True")
For Each objItem in colItems
 Wscript.Echo "Local Account: " & objItem.LocalAccount & VBNewLine _
 & "Name: " & objItem.Name & VBNewLine _
 & "SID: " & objItem.SID & VBNewLine _
 & "SID Type: " & objItem.SIDType & VBNewLine _
 & "Status: " & objItem.Status & VBNewLine
Next

PowerShell
`$Accts=Get-WMIObjectWin32_Group\|where {$_.LocalAccount} $accts \|ftName, Sid, SidType, Status-autosize`

Feedback

Was this page helpful?

Additional resources

Last updated on

URL: https://learn.microsoft.com/en-us/windows/win32/wmisdk/wmi-tasks--accounts-and-domains