VOOZH about

URL: https://oeis.org/A063198

⇱ A063198 - OEIS

login
A063198
Dimension of the space of weight 2n cuspidal newforms for Gamma_0( 10 ).
1
0, 1, 3, 1, 3, 5, 3, 5, 7, 5, 7, 9, 7, 9, 11, 9, 11, 13, 11, 13, 15, 13, 15, 17, 15, 17, 19, 17, 19, 21, 19, 21, 23, 21, 23, 25, 23, 25, 27, 25, 27, 29, 27, 29, 31, 29, 31, 33, 31, 33
OFFSET
1,3
COMMENTS
The dimension of weight n is apparently given by 0, 0, 2, 1, 0, 3, 2, 1, 4,... etc as in A063942. - R. J. Mathar, Jul 14 2015
FORMULA
G.f.: x^2*(1+2*x-2*x^2+x^3) / ( (1+x+x^2)*(x-1)^2 ). - R. J. Mathar, Jul 15 2015
For n>1, a(n) = (6*n-3+12*cos(2*n*Pi/3)-4*sqrt(3)*sin(2*n*Pi/3))/9. - Wesley Ivan Hurt, Sep 30 2017
MAPLE
s0star := proc(n)
local pf, a, p, e ;
if n = 1 then
1;
else
a :=1 ;
for pf in ifactors(n)[2] do
p := op(1, pf) ;
e := op(2, pf) ;
if e =1 then
a := a*(1-1/p) ;
elif e = 2 then
a := a*(1-1/p-1/p^2) ;
else
a := a*(1-1/p)*(1-1/p^2) ;
end if;
end do:
a ;
end if;
end proc:
nuInfstar := proc(n)
local pf, a, p, e ;
if n = 1 then
1;
else
a :=1 ;
for pf in ifactors(n)[2] do
p := op(1, pf) ;
e := op(2, pf) ;
if type(e, 'odd') then
return 0;
elif e = 2 then
a := a*(p-2) ;
else
a := a*(p-1)^2*p^(e/2-2) ;
end if;
end do:
a ;
end if;
end proc:
nu2star := proc(n)
local pf, a, p, e ;
if n = 1 then
1;
else
a :=1 ;
for pf in ifactors(n)[2] do
p := op(1, pf) ;
e := op(2, pf) ;
if p = 2 then
if e =1 or e =2 then
a := -a ;
elif e =3 then
;
else
return 0 ;
end if;
elif modp(p, 4) = 1 then
if e = 2 then
a := -a ;
else
return 0;
end if;
else
if e = 1 then
a := -2*a ;
elif e = 2 then
;
else
return 0;
end if;
end if;
end do:
a ;
end if;
end proc:
nu3star := proc(n)
local pf, a ;
if n = 1 then
1;
else
a :=1 ;
for pf in ifactors(n)[2] do
p := op(1, pf) ;
e := op(2, pf) ;
if p = 3 then
if e =1 or e =2 then
a := -a ;
elif e =3 then
;
else
return 0 ;
end if;
elif modp(p, 3) = 1 then
if e = 2 then
a := -a ;
else
return 0;
end if;
else
if e = 1 then
a := -2*a ;
elif e = 2 then
;
else
return 0;
end if;
end if;
end do:
a ;
end if;
end proc:
c2 := proc(k)
1/4+floor(k/4)-k/4 ;
end proc:
c3 := proc(k)
1/3+floor(k/3)-k/3 ;
end proc:
g0star := proc(k, N)
local a;
a := (k-1)/12*N*s0star(N) -nuInfstar(N)/2 +c2(k)*nu2star(N)+c3(k)*nu3star(N) ;
if k/2 = 1 then
a := a+numtheory[mobius](N) ;
end if;
a;
end proc:
A063198 := proc(n)
g0star(2*n, 10) ;
end proc:
A063199 := proc(n)
g0star(2*n, 11) ;
end proc:
A063200 := proc(n)
g0star(2*n, 15) ;
end proc:
A063201 := proc(n)
g0star(2*n, 18) ;
end proc:
A063205 := proc(n)
g0star(2*n, 29) ;
end proc: # R. J. Mathar, Jul 19 2024
CROSSREFS
Cf. A063942.
Sequence in context: A284130 A005474 A012264 * A122582 A173039 A016471
KEYWORD
nonn,easy
AUTHOR
N. J. A. Sloane, Jul 10 2001
STATUS
approved